Windows10 のキーボードをAutoHotKeyでカスタマイズ　～カーソルキーを無変換キー＋HJKL(Vim風) で操作する他～

2021年1月31日2021年5月9日Windows

ホームポジションを崩さずにタイピングしたい

長年、Windows でキーボードのカスタマイズは CapsLock キーを Ctrl キーに置き換えるのみでした。

しかし、カーソルキーを操作するとホームポジションが崩れることがストレスに感じることが多くなってきたので、AutoHotKeyを用いてキーボードのカスタマイズを行ってみました。

カスタマイズした内容で５カ月ほど利用していますが、今のところ満足していますので、これからキーボードカスタマイズしようと考えている方は参考にしてみてください。

（2021/5/8 追記）Enterキーのショートカット割当も追加し、より快適になりました！

キーボードカスタマイズの内容

考え方としてはホームポジションから遠い位置にあるキーを利用しなくてもいいようにします。

CapsLock キー Ctrl キーとして利用する
カーソルキーを無変換＋ HJKL で操作する
Home、End を無変換＋ AE で操作する
Backspace、Delete を無変換＋ NM で操作する
Enter を無変換＋ ;(セミコロン)や:(コロン)で操作する
単語単位のカーソル移動を無変換＋ UI で操作する
カーソル位置から行末まで切り取りを無変換＋ O で操作する
PageUp、PageDown を変換＋ JK で操作する
Home、End を変換＋ HL で操作する
Alt ＋ ←、Alt ＋ → を変換＋ UI で操作する
変換、無変換キーで IME のオン・オフを切り替える

実現方法の概要

ショートカットキーの割当方法として、CapsLock キーを F13 キーに割り当てて、「F13＋○キー」の方法がよく紹介されていたので、一度試してみたのですが、長年 CapsLock キーを Ctrl キーとして利用し、その操作に慣れてしまったので、CapsLockキーを用いたショートカットキーの割当は私にはあっていませんでした。

そこで、CapsLockキーの代わりに目をつけたのが「無変換キー」と「変換キー」です。

CapsLockキーよりも親指で押しやすい位置にある「無変換キー」や「変換キー」を用いたショートカットキーは５ヶ月ほど利用していて、手に負担のないい位置にあることも実感していますのでおすすめのキーです。

「無変換キー」と「変換キー」＋ ○ キーのようなショートカットキーを作成することで、ホームポジションから遠い位置にあるキーに手を伸ばさなくても良いようにしていきます。

利用するソフトウェア

ChangeKey
AutoHotKey

ChangeKey のインストールと設定手順

ChangeKey とは

キーボードの各キーを別のキーに割り当てることができるソフトです。

レジストリを変更しますのでソフトに依存せずにカスタマイズできるのが良いところです。

ChangeKey でやりたいこと

CapsLock キーを Ctrl キーに割り当て

カーソルキーの操作とは直接関係ないですが、Ctrlキーがキーボードの左下にあるのは、長時間操作していると小指に疲れが溜まってきてしまうので、ほとんど利用価値のないCapsLockキーにはCtrlキーとして働いてもらうことにします。

他にも、「カタカナ、ひらがな、ローマ字」キーなども別のキーに割り当てるなどを行ってみても良いかもしれません。

例えば、Escキーも遠い位置にありますので「カタカナ、ひらがな、ローマ字」キーをEscキーに割り当ててみても使いやすかもしれません。

ChangeKey のインストール手順

以下のリンクからChangeKeyをダウンロードします。

ChangeKey

ファイルをダウンロードし、適当なディレクトリに展開します。

ChangeKey の設定手順

ChangeKey はレジストリへ登録しますので「管理者として実行」する必要があります。

起動するとこのようなキーボードの画面が表示されます。

CapsLock キーを Ctrl キーに割り当て

CapsLock キーを選択すると、以下のように青枠で囲まれた状態になります。

変更したいキーである「Ctrl 左」キーを選択します。

レジストリに登録する

[登録] – [現在の設定内容で登録します]をクリック

レジストリ登録後に再起動することでキー設定が反映されます。

AutoHotKey のインストールと設定手順

AutoHotKey とは

ショートカットキーの作成やマウス操作をキーボードで操作することもできるソフトです。

AutoHotKey でやりたいこと

AutoHotKey を利用して、「無変換キー」＋ ○ キーや「変換キー」＋○キーの各ショートカットを登録します。

具体的には、以下の内容を登録していきます。

無変換キーをベースにしたショートカットキー

カーソルキーを無変換＋ HJKL で操作する
Home、End を無変換＋ AE で操作する
Backspace、Delete を無変換＋ NM で操作する
Enter を無変換＋ ;(セミコロン)や:(コロン)で操作する
単語単位のカーソル移動を無変換＋ UI で操作する
カーソル位置から行末まで切り取りを無変換＋ O で操作する

変換キーをベースにしたショートカットキー

PageUp、PageDown を変換＋ JK で操作する
Home、End を変換＋ HL で操作する
Alt ＋ ←、Alt ＋ → を変換＋ UI で操作する

AutoHotKey のインストール

以下のリンクから AutoHotKey をダウンロードします。

AutoHotKey

ダウンロードしたファイル（AutoHotkey_1.1.33.02_setup.exeなど）を実行しインストールします。

AutoHotKey の設定手順

AutoHotKeyは拡張子が「ahk」のテキストファイルを作成し設定します。（keysetting.ahk　など）

基本的には[実際に押すキー]::[変換したいキー]で設定します。

「無変換キー」+ ○のように複数の組み合わせの場合は、「&」で結合し設定します。

; ■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■
; 無変換キーをベースとしたショートカットキー割当
; ■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■

; 無変換の単発押しは無変換
vk1D::vk1D

; ----------------------------------
; vimのcursolkey
; ----------------------------------
vk1D & h::Left
vk1D & j::Down
vk1D & k::Up
vk1D & l::Right

; ----------------------------------
; word jump
; ----------------------------------
vk1D & u::
  if GetKeyState("Shift") {
    Send ^+{Left}
    return
  }
  Send ^{Left}
  return

vk1D & i::
  if GetKeyState("Shift") {
    Send ^+{Right}
    return
  }
  Send ^{Right}
  return

; ----------------------------------
; コロン(vkBA)とセミコロン(vkBB)をEnter
; ----------------------------------
vk1D & vkBA::Enter
vk1D & vkBB::Enter

; ----------------------------------
; Home/End/BS/Del
; ----------------------------------
vk1D & a::Home
vk1D & e::End
vk1D & n::BS
vk1D & m::Del

; ----------------------------------
; カーソル位置から行末まで削除
; ----------------------------------
vk1D & o::
  send {ShiftDown}{End}{ShiftUp}
  send ^c
  send {Del}
  return


; ■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■
; 変換キーをベースとしたショートカットキー割当
; ■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■

; 変換の単発押しは変換
vk1C::vk1C

; ----------------------------------
; fu+cursolkey
; ----------------------------------
vk1C & h::Home
vk1C & j::PgDn
vk1C & k::PgUp
vk1C & l::End

; ----------------------------------
; Alt＋カーソル
; ----------------------------------
vk1C & u::!Left
vk1C & i::!Right

ポイント

無変換キーと変換キーはIME の ON/OFF 機能として利用したいため、元々の機能である無変換キーや変換キーとして動作させる設定にしています。
（単独で押された場合はそのキーとして動作するようにしている）